***************************************************************************
* PSPICE Library of USCi 1200V-10A SiC JBS Diode UJ2D1210T
* Copyright	: United Silicon Carbide, Inc.
* Revision		: 1.0  
* Release Date	: 30-Jan-2014
***************************************************************************
* DISCLAIMER:
*	This model is constructed based on the typical characteristics of
* the device shown in the datasheet and is not warranted by USCi as
* fully representing all of the specifications and operating
* characteristics of the device. The bipolar injection characteristic
* of the device has not been modelled. This model is valid for the 
* temperature range of -55°C to 175°C. 
*	This model is intended for use by customers in the design of 
* electrical circuits using USCi SiC products. No responsibility for
* inaccuracies can be assumed by USCi. USCi does not assume any liability
* arising out of the use of the data or circuits builts therefrom. USCi
* reserves the right to make any change to the model without prior notice.
***************************************************************************

.subckt UJ2D1210T nAnode nCathode
La	nAnode	na		6n
Rla	nAnode	na		200
D1a   na   nk Dtemp
Gleak na   nk value={-Ir_Io(TEMP+273.15)*exp(V(nk,na)*Ir_alpha(TEMP+273.15))}
Lk	nk	nCathode	1n
Rlk	nk	nCathode	200
.MODEL Dtemp D
+ IS=1.100E-16
+ N=1.03  XTI=7
+ RS=.047 TRS1=7.8831e-3 TRS2=4.1837e-5
+ BV = 1800 IBV =1e-10 TBV1=1e-4
+ CJO=6.36e-10
+ M=.45
+ VJ=1.25
+ FC=0.999
+ TT=254.33E-12
.FUNC Ir_Io(tmp) {-4.968e-18*pwr(tmp,4)+4.667e-15*pwr(tmp,3)-1.192e-12*tmp*tmp+2.697e-11*tmp+1.5897e-8}
.FUNC Ir_alpha(tmp) {-3.507e-11*pwr(tmp,3)+1.263e-8*tmp*tmp+1.385e-6*tmp+7.214e-3}
.ends