***************************************************************************
* PSPICE Library of USCi 650V-10A SiC JBS Diode UJD06510T
* Copyright	: United Silicon Carbide, Inc.
* Revision		: 1.0  
* Release Date	: 13-Jan-2015
* Note: This model contains two UJD06510T connected in parallel
***************************************************************************
* DISCLAIMER:
*	This model is constructed based on the typical characteristics of
* the device shown in the datasheet and is not warranted by USCi as
* fully representing all of the specifications and operating
* characteristics of the device. The bipolar injection characteristic
* of the device has not been modelled. This model is valid for the 
* temperature range of -55¡C to 175¡C. 
*	This model is intended for use by customers in the design of 
* electrical circuits using USCi SiC products. No responsibility for
* inaccuracies can be assumed by USCi. USCi does not assume any liability
* arising out of the use of the data or circuits builts therefrom. USCi
* reserves the right to make any change to the model without prior notice.
***************************************************************************

.SUBCKT UJD06520K nAnode nCathode
XD1	nAnode nCathode		UJD06510T
XD2	nAnode nCathode		UJD06510T
.ends

.SUBCKT UJD06510T nAnode nCathode
La	nAnode	na		6n
Rla	nAnode	na		200
D1a   na   nk Dtemp
Gleak na   nk value={-Ir_Io(TEMP+273.15)*exp(V(nk,na)*Ir_alpha(TEMP+273.15))}
Lk	nk	nCathode	1n
Rlk	nk	nCathode	200
.MODEL Dtemp D
+ IS=1.100E-16
+ N=1.03  XTI=7
+ RS=.047 TRS1=6.5856e-3 TRS2=3.8316e-5
+ BV = 950 IBV =1e-10 TBV1=1e-4
+ CJO=3.73e-10
+ M=.45
+ VJ=1.37
+ FC=0.999
+ TT=254.33E-12
.FUNC Ir_Io(tmp) {3.9e-18*pwr(tmp,4)-3.9e-15*pwr(tmp,3)+1.467e-12*tmp*tmp-2.45e-10*tmp+1.566e-8}
.FUNC Ir_alpha(tmp) {-1.363e-10*pwr(tmp,3)+6.588e-9*tmp*tmp+3.4e-5*tmp+8.709e-3}
.ends